kwin/kcmkwin/kwinrules/package/contents/ui/FileDialogLoader.qml

/*
 * Copyright (c) 2020 Ismael Asensio <isma.af@gmail.com>
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License as
 * published by the Free Software Foundation; either version 2 of
 * the License or (at your option) version 3 or any later version
 * accepted by the membership of KDE e.V. (or its successor approved
 * by the membership of KDE e.V.), which shall act as a proxy
 * defined in Section 14 of version 3 of the license.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */

import QtQuick 2.14
import QtQuick.Dialogs 1.0 as QtDialogs

Loader {
    id: root
    active: false

    property string title : i18n("Select File");
    property string lastFolder : ""
    property bool isSaveDialog : false

    signal fileSelected(string path)

    sourceComponent: QtDialogs.FileDialog {
        id: fileDialog

        title: root.title
        selectExisting: !root.isSaveDialog
        folder: root.lastFolder || shortcuts.home
        nameFilters: [ i18n("KWin Rules (*.kwinrule)") ]
        defaultSuffix: "*.kwinrule"

        Component.onCompleted: {
            open();
        }

        onAccepted: {
            root.lastFolder = folder;
            if (fileUrl != "") {
                root.fileSelected(fileUrl);
            }
            root.active = false;
        }

        onRejected: {
            root.active = false;
        }
    }
}